人気ブログランキング | 話題のタグを見る
<< Google Chromeでマ... Google Chrome@U... >>
 

Google Chrome をUSBメモリで起動する試み

はじめに

Googleのブラウザの、Google ChromeをUSBフラッシュメモリから起動してみたくなりました。まだちゃんと解析していないので、これは私の覚書です。DOS窓を消す作業もまだ行っていません。インストーラを作っていません。

なお、このアプリによって発生したいかなる損害について私は責任を負いかねますのであらかじめご了承下さい。

※まだいっぱい不具合ありそう。もう少し、調べないと・・・

バージョン:0.2.149.27
OS:Windows XP

2008年09月05日 修正
Google Chrome USBを入れたドライブのルートにDefaultフォルダと、Safe Browsing Filter、Safe Browsingファイルが作成されちゃいます。新しいコードに書き換えて使って下さい。なお、フォルダとファイルをGoogle Chrome USBを入れたフォルダに移動すれば、今までの設定は引き継ぐことができそうです。


準備


1.Google Chromeをインストールする。
2.Winキー+Rでファイル名を指定して実行を表示させる。
3.以下のコマンドを入力する。

コマンド


"%USERPROFILE%\Local Settings\Application Data"



4.エクスプローラが起動するので、GoogleをUSBフラッシュメモリなどに入れる。

5. Google Chromeをアンインストールする。

6. 以下のコードをコピーして、USBフラッシュメモリのGoogleフォルダと同じ場所にChrome@USB.batとして保存する。(Googleのフォルダに入れるのではなく、Googleのフォルダの外です。)

Google Chrome をUSBメモリで起動する試み_a0031863_1183120.gif

図1 Chrome@USB.batの保存場所

6.Chrome@USB.batをダブルクリックで実行する。


実行用コード





Chrome@usb.bat 2008.09.05.01


:: Chrome@USB Ver. 0.2.149.27 - 2008.09.05.01
:: 2008.09.04.01 * とりあえず作ってみる
:: 2008.09.05.01 * Safe BrowsingとDefaultフォルダがルートに作成されるバグを修正。仮想ドライブで対応
::               * Google Chromeが入っている場合はレジストリの処理を行わないように修正。
::               * DOS窓を隠す
::               * Prefetchの処理未定。
::               * 仮想ドライブをo~zまで空きを探すように変更。
@echo off
%~d0
cd %~dp0

set odrv=%~d0
set defaultexe=%USERPROFILE%\Local Settings\Application Data\Google\Chrome\Application\chrome.exe
set regroot=HKCU\Software\Google\Update\Clients\{8A69D345-D564-463c-AFF1-A69D9E530F96}
set ver=0.2.149.27


::DOS窓の非表示
set my=%~nx0
if "%1" == "" (
call :make
start cscript //nologo run.js
goto :EOF
)


::仮想ドライブの作成(o~zの空きドライブを割り当てる)
for %%d in (o p q r s t u v w x y z) do if not exist %%d:\nul set drv=%%d
subst %drv%: %cd%
%drv%:


::起動用レジストリの作成
if not exist "%defaultexe%" (
reg ADD %regroot% /f
reg ADD %regroot% /v name /t REG_SZ /d Chrome  /f
reg ADD %regroot% /v pv /t REG_SZ /d %ver%  /f
)


::作業フォルダ
if not exist temp\null md temp
set TEMP=%cd%\temp
set TMP=%cd%\temp

::実行
set USERPROFILE=%cd%
%cd%\Google\Chrome\Application\chrome.exe


%odrv%
subst %drv%: /d


::起動用レジストリの削除
if not exist "%defaultexe%" reg DELETE "%regroot%" /f
goto :EOF


:make
echo WScript.CreateObject("WScript.Shell").Run('cmd /c %my% hide',0,0);>run.js
goto :EOF




Chrome@usb.bat



%~d0
cd %~dp0

:: 起動のためのレジストリを作成
REG ADD HKCU\Software\Google\Update\Clients\{8A69D345-D564-463c-AFF1-A69D9E530F96} /f

reg ADD HKCU\Software\Google\Update\Clients\{8A69D345-D564-463c-AFF1-A69D9E530F96} /v name /t REG_SZ /d Chrome  /f
reg ADD HKCU\Software\Google\Update\Clients\{8A69D345-D564-463c-AFF1-A69D9E530F96} /v pv /t REG_SZ /d 0.2.149.27  /f


set USERPROFILE=%cd%

%cd%\Google\Chrome\Application\chrome.exe


::レジストリの削除
reg DELETE "HKCU\Software\Google\Update\Clients\{8A69D345-D564-463c-AFF1-A69D9E530F96}" /f





最後に

バージョン依存が激しいので、動かなない場合もありそうです。もう少し調べてチャレンジできるといいなぁ。
とりあえず、休み時間に試した結果です。他にもっと良い方法があるかもしれませんね。



あ、こんなものがあったorz

あ、すでにあるみたいです。私としたことが。Google Chromeの調査する必要なかったみたいorz
とほほほです。

これであなたもGoogle Chrome伝道師「Portable Chrome」


記事の下の方に広告が表示される場合があります。この広告はエキサイトの広告枠です。
by potto37 | 2008-09-05 18:16
<< Google Chromeでマ... Google Chrome@U... >>
掲載の記事や画像などすべての複写・転載・公衆送信等はご遠慮ください。